Upgrade to postgresql 17

This commit is contained in:
alejandro-angulo 2025-07-12 10:31:56 -07:00
parent f5e5805a6b
commit 1f5ae130f5
Signed by: alejandro-angulo
GPG key ID: 75579581C74554B6
2 changed files with 58 additions and 0 deletions

View file

@ -0,0 +1,52 @@
{
config,
lib,
pkgs,
namespace,
...
}:
let
cfg = config.${namespace}.services.postgresql;
postgresql_cfg = config.services.postgresql;
in
{
options.${namespace}.services.postgresql = {
upgradeScript = {
enable = lib.mkEnableOption "postgres upgrade script (see here: https://nixos.org/manual/nixos/stable/#module-services-postgres-upgrading";
newVersion = lib.mkOption {
type = lib.types.package;
description = "Version of postgres to upgrade to";
};
currentVersion = lib.mkOption {
type = lib.types.package;
description = "Current postgres version";
default = postgresql_cfg.package;
};
};
};
config = lib.mkIf cfg.upgradeScript.enable {
environment.systemPackages = [
(pkgs.writeScriptBin "upgrade-pg-cluster" ''
set -eux
systemctl stop postgresql
export NEWDATA="/var/lib/postgresql/${cfg.upgradeScript.newVersion.psqlSchema}"
export NEWBIN="${cfg.upgradeScript.newVersion}/bin"
export OLDDATA="${postgresql_cfg.dataDir}"
export OLDBIN="${postgresql_cfg.finalPackage}/bin"
install -d -m 0700 -o postgres -g postgres "$NEWDATA"
cd "$NEWDATA"
sudo -u postgres "$NEWBIN/initdb" -D "$NEWDATA" ${lib.escapeShellArgs postgresql_cfg.initdbArgs}
sudo -u postgres "$NEWBIN/pg_upgrade" \
--old-datadir "$OLDDATA" --new-datadir "$NEWDATA" \
--old-bindir "$OLDBIN" --new-bindir "$NEWBIN" \
"$@"
'')
];
};
}

View file

@ -37,6 +37,10 @@
enable = true;
enableServer = true;
};
services.postgresql.upgradeScript = {
enable = false;
newVersion = pkgs.postgresql_17;
};
services.loki.enable = true;
services.promtail.enable = true;
services.teslamate = {
@ -108,6 +112,8 @@
];
};
services.postgresql.package = pkgs.postgresql_17;
# List packages installed in system profile. To search, run:
# $ nix search wget
environment.systemPackages = with pkgs; [